oracle将数据导出到CSV文件-ok
oracle将数据导出到CSV文件-ok
·
工作中有需要将线上数据导出到excel给客户分析/查看的情况,如下是方法介绍情况:
utl_file读写文件包 ,1分钟导出的数据量 大概是300万 适用于大量导出时
spool 循环打印 ,适用小型数据量时。
1、创建用于导出数据的存储过程
利用utl_file导出.csv文件
首先在oracle数据库中建立sql_to_csv存储过程,代码如下:
CREATE OR REPLACE PROCEDURE SQL_TO_CSV
(
P_QUERY IN VARCHAR2, -- PLSQL文
P_DIR IN VARCHAR2, -- 导出的文件放置目录
P_FILENAME IN VARCHAR2 -- CSV名
)
IS
L_OUTPUT UTL_FILE.FILE_TYPE;
L_THECURSOR INTEGER DEFAULT DBMS_SQL.OPEN_CURSOR;
L_COLUMNVALUE VARCHAR2(4000);
L_STATUS INTEGER;
L_COLCNT NUMBER := 0;
L_SEPARATOR VARCHAR2(1);
L_DESCTBL DBMS_SQL.DESC_TAB;
P_MAX_LINESIZE NUMBER := 32000;
BEGIN
--OPEN FILE
L_OUTPUT := UTL_FILE.FOPEN(P_DIR, P_FILENAME, 'W', P_MAX_LINESIZE);
--DEFINE DATE FORMAT
EXECUTE IMMEDIATE 'ALTER SESSION SET NLS_DATE_FORMAT=''YYYY-MM-DD HH24:MI:SS''';
--OPEN CURSOR
DBMS_SQL.PARSE(L_THECURSOR, P_QUERY, DBMS_SQL.NATIVE);
DBMS_SQL.DESCRIBE_COLUMNS(L_THECURSOR, L_COLCNT, L_DESCTBL);
--DUMP TABLE COLUMN NAME
FOR I IN 1 .. L_COLCNT LOOP
UTL_FILE.PUT(L_OUTPUT,L_SEPARATOR || '"' || L_DESCTBL(I).COL_NAME || '"'); --输出表字段
DBMS_SQL.DEFINE_COLUMN(L_THECURSOR, I, L_COLUMNVALUE, 4000);
L_SEPARATOR := ',';
END LOOP;
UTL_FILE.NEW_LINE(L_OUTPUT); --输出表字段
--EXECUTE THE QUERY STATEMENT
L_STATUS := DBMS_SQL.EXECUTE(L_THECURSOR);
--DUMP TABLE COLUMN VALUE
WHILE (DBMS_SQL.FETCH_ROWS(L_THECURSOR) > 0) LOOP
L_SEPARATOR := '';
FOR I IN 1 .. L_COLCNT LOOP
DBMS_SQL.COLUMN_VALUE(L_THECURSOR, I, L_COLUMNVALUE);
UTL_FILE.PUT(L_OUTPUT,
L_SEPARATOR || '"' ||
TRIM(BOTH ' ' FROM REPLACE(L_COLUMNVALUE, '"', '""')) || '"');
L_SEPARATOR := ',';
END LOOP;
UTL_FILE.NEW_LINE(L_OUTPUT);
END LOOP;
--CLOSE CURSOR
DBMS_SQL.CLOSE_CURSOR(L_THECURSOR);
--CLOSE FILE
UTL_FILE.FCLOSE(L_OUTPUT);
EXCEPTION
WHEN OTHERS THEN
RAISE;
END;
/
2、查询及创建 directory
set lines 200 pages 200
col owner for a30
col directory_name for a30
col directory_path for a85
select * from dba_directories ;
OWNER DIRECTORY_NAME DIRECTORY_PATH
------------------------------ ------------------------------ -------------------------------------------------------------------------------------
SYS DATA /u01/app
SYS EXPDP_DIR /u01/app/expdp_bak
SYS XMLDIR /u01/app/oracle/product/11.2.0/dbhome_1/rdbms/xml
SYS ORACLE_OCM_CONFIG_DIR /u01/app/oracle/product/11.2.0/dbhome_1/ccr/hosts/LG-MySQL-TestDB-92/state
SYS DATA_PUMP_DIR /u01/app/oracle/admin/lgdata/dpdump/
SYS ORACLE_OCM_CONFIG_DIR2 /u01/app/oracle/product/11.2.0/dbhome_1/ccr/state
或者创建directory
sql> create or replace directory OUT_PATH as '/u01/app/';
sql> grant read,write on directory OUT_PATH to public;
3、导出数据
3.1、数据库表导出语句
SQL> exec sql_to_csv('select * from LG_BANKNO_BNB_test','DATA','ehy.lg_bankno_bnb_test.csv');
PL/SQL procedure successfully completed.
3.2、带where 条件的sql
SQL> exec sql_to_csv('select * from LG_BANKNO_BNB_test where BANKCODE=402452106054','DATA','ehy.lg_bankno_bnb_test.csv');
PL/SQL procedure successfully completed.
3.3、带where 条件的sql 并且指定需要的列
SQL> exec sql_to_csv('select BANKCODE,BANKNAME from LG_BANKNO_BNB_test where BANKCODE=402452106054','DATA','ehy.lg_bankno_bnb_test.csv');
PL/SQL procedure successfully completed.
3.4、导出两表join的sql
具体SQL语句如下
select distinct b_BANKCODE,b_BANKNAME
from (select a.BANKCODE as a_BANKCODE,a.BANKNAME as a_BANKNAME,
b.BANKCODE as b_BANKCODE,b.BANKNAME as b_BANKNAME
from LG_BANKNO_BNB a,LG_BANKNO_BNB_test b
where a.BANKCODE=b.BANKCODE)
where a_BANKCODE is null ;
SQL> exec sql_to_csv('select distinct b_BANKCODE,b_BANKNAME from (select a.BANKCODE as a_BANKCODE,a.BANKNAME as a_BANKNAME, b.BANKCODE as b_BANKCODE, b.BANKNAME as b_BANKNAME from LG_BANKNO_BNB a,LG_BANKNO_BNB_test b where a.BANKCODE=b.BANKCODE) where a_BANKCODE is null','DATA','ehy.lg_bankno_bnb_test.csv');
PL/SQL procedure successfully completed.
说明:sql 必须一行书写,不能换行,否则会报错!!!
其实可以将上面的sql 先变成一个视图 view,然后再导出这个视图 view
3.5、导出视图的数据
create view sql_to_csv_view as
select distinct b_BANKCODE,b_BANKNAME
from (select a.BANKCODE as a_BANKCODE,a.BANKNAME as a_BANKNAME,
b.BANKCODE as b_BANKCODE,b.BANKNAME as b_BANKNAME
from LG_BANKNO_BNB a,LG_BANKNO_BNB_test b
where a.BANKCODE =b.BANKCODE)
where a_BANKCODE is not null ;
SQL> exec sql_to_csv('select * from sql_to_csv_view','DATA','ehy.lg_bankno_bnb_test.csv');
PL/SQL procedure successfully completed.
--删除视图
drop view sql_to_csv_view ;
3.6、生成批量导出数据
SELECT 'EXEC sql_to_csv(''select * from ' ||T.TABLE_NAME ||''',''DATA''' || ',''ODS_MDS.' || T.TABLE_NAME ||'.csv'');' FROM user_TABLES T where t.TABLE_NAME='表名' ;
# 生成的sql如下:
EXEC sql_to_csv('select * from LG_BANKNO_BNB_test','DATA','ehy.lg_bankno_bnb_test.csv');
EXEC sql_to_csv('select * from TD_DIS_BATCH_CHECK','DATA','ODS_MDS.TD_DIS_BATCH_CHECK.csv');
EXEC sql_to_csv('select * from TD_DIS_CONTROLL','DATA','ODS_MDS.TD_DIS_CONTROLL.csv');
EXEC sql_to_csv('select * from TD_DIS_TASK_DATASOURCE','DATA','ODS_MDS.TD_DIS_TASK_DATASOURCE.csv');
EXEC sql_to_csv('select * from TD_DIS_TASK_DEPENDENT','DATA','ODS_MDS.TD_DIS_TASK_DEPENDENT.csv');
EXEC sql_to_csv('select * from TD_DIS_TASK_GROUP','DATA','ODS_MDS.TD_DIS_TASK_GROUP.csv');
更多推荐
已为社区贡献4条内容
所有评论(0)